Go to the first, previous, next, last section, table of contents.

スタイルガイド

もちろん、人それぞれにフォーマットの好みがありますが、読みやすく、理解しやすく、保守しやすいプログラムにするための一般的なガイドラインも存在します。

コードレイアウトの美学に関して、唯一 Larry が強く気にかけることは、複数行に渡る BLOCK の閉じ中括弧の位置を、その構文を開始するキーワードとカラム位置を揃えるということです。この他には、それ程に強くはない好みとして:

4カラムのインデント。
開き中括弧は、できるだけキーワードと同じ行におくようにする。さもなくば、キーワードとカラムを揃える。
複数行ブロックの中括弧の前は空ける。
1行の BLOCK は中括弧も含めて1行にしてよい。
セミコロンの前には空白を入れない。
「短い」1行の BLOCK では、セミコロンを省く。
ほとんどの演算子の両側には空白を入れる。
(大括弧の中の) 「複雑な」添字の両側には空白を入れる。
動作内容の異なる、かたまりごとに空行を入れる。
else は行替えする。
関数名と開き括弧の間に空白を入れない。
コンマのあとには空白を入れる。
長い行は (and と or 以外の) 演算子のあとで改行する。
その行内でマッチする最後の括弧の後にスペースを入れる。
対応する項目は、カラムを揃えて縦に整列する。
明瞭さの妨げにならない範囲で、余分な句読点などは省く。

Larry はこれらのことに対して彼なりの理由を持っていますが、他の人が同じように考えなくても文句をいう筋合いのものではありません。

もう少し本質的なスタイルの問題も考えておくべきでしょう:

何らかの方法で書けるからといって、その方法でやらなくてはならないことはありません。Perl は何でもいくつかの方法でできるように設計されていますので、もっとも読みやすいものを選ぶとよいでしょう。たとえば、
```
open(FOO,$foo) || die "Can't open $foo: $!";
```
という方が
```
die "Can't open $foo: $!" unless open(FOO,$foo);
```
のように、文の重要なポイントを修飾子に隠してしまうよりも良いでしょう。また、
```
print "Starting analysis\n" if $verbose;
```
の方が
```
$verbose && print "Starting analysis\n";
```
よりも良いでしょう。使う人が `-v' と入力したかどうかを判定するのがポイントではないからです。同様に、演算子にデフォルトの値が用意されているからといって、それを利用しなければならないというものではありません。デフォルトは、怠け者のシステムプログラマが「一時的な」プログラムを書くためにあるのです。プログラムを読みやすくしたいと思うならば、ちゃんと引数を与えるようにしてください。さらには、多くの場所で括弧を省くことができますが、これは決して省かなければならないということではありません:
```
return print reverse sort num values %array;
return print(reverse(sort num (values(%array))));
```
疑わしいときには括弧を付けるべきです。少なくとも、viで % キーを使って、跳ねまわることができます。特に疑わしい場合でなくても、みなさんの後を引き継いでコードのメンテをする人のことを考えてあげてください。間違ったところに括弧を付けてしまうかも知れません。
ループの最初や最後で抜けられるように、妙に莫迦げた細工をしないこと。Perl では、last 演算子を用意しているので、ループの途中で抜けることができるのです。目立つように、少しばかり突き出して置けばよいのです:
```
LINE:
    for (;;) {
        statements;
      last LINE if $foo;
        next LINE if /^#/;
        statements;
    }
```
ループラベルを付けるのを恐れてはいけません。多重のループからの脱出するためでもありますが、読みやすくするためでもあるのです。上の例を参照してください。
移植性のため、すべてのマシンでインプリメントされていない機能を使う場合には、 eval の中で使ってみて調べてください。その機能がインプリメントされているバージョンやパッチレベルがわかるのであれば、 $] (English モジュールを使っているときには $PERL_VERSION ) を調べて、実装されているかを見ることができます。 `Config' モジュールで Perl をインストールした時に、 Configure プログラムで決定された値を引き出すことができます。
意味のある識別子名を使ってください。何を意味しているのかがわからなくなれば、きっと問題になるでしょう。
ごちゃごちゃした正規表現には、 /x 修飾子を使って、空白を入れ、なるべく見やすくするようにしましょう。正規表現の中にスラッシュやバックスラッシュを使っている時には、区切文字にスラッシュを使うのは避けましょう。
リスト演算子に括弧を付けなければならなくなるのを避け、 && や || といった記号的な演算子の頻度を下げるために " and "や " or " という新しい演算子を使ってください。過剰な & や括弧を避けるために、サブルーティンは関数やリスト演算子として使いましょう。
何回も print() 文を繰り返すよりは、ヒアドキュメントを使ってください。

対応するものは縦に並べましょう。特に 1 行に収まらないくらい長い場合には。

$IDX = $ST_MTIME;
$IDX = $ST_ATIME       if $opt_u;
$IDX = $ST_CTIME       if $opt_c;
$IDX = $ST_SIZE        if $opt_s;

mkdir $tmpdir, 0700 or die "can't mkdir $tmpdir: $!";
chdir($tmpdir)      or die "can't chdir $tmpdir: $!";
mkdir 'tmp',   0777 or die "can't mkdir $tmpdir/tmp: $!";

変換を行なうときに並べることでわかりやすくなるならば、並べましょう。
```
tr [abc]
   [xyz];
```
再利用性を考えましょう。同じようなことをまたしなくてはならないかもしれないときに、一時凌ぎのスクリプトに頭を悩ませることはないでしょう。コードを一般化することを考えてください。モジュールやオブジェクトクラスを書くことを考えてください。 use strict や `-w' を有効にして、コードの不明瞭な部分が無いようにしてください。コードを減らすことを考えてください。全体の見方を変えることも考えてください。さらに ... やめましょう。
一貫性をもって。
良識をもって。

Go to the first, previous, next, last section, table of contents.